1 files changed, 47 insertions, 0 deletions
diff --git a/tox-weechat-git-nogaems/PKGBUILD b/tox-weechat-git-nogaems/PKGBUILD
new file mode 100644
index 0000000..c54b317
--- /dev/null
+++ b/tox-weechat-git-nogaems/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+
+_pkgname=tox-weechat
+pkgname=${_pkgname}-git-nogaems
+pkgver=r337.ecf3467
+pkgrel=2
+pkgdesc='Tox protocol plugin for WeeChat'
+arch=('i686' 'x86_64')
+url='https://github.com/haavardp/tox-weechat'
+license=('GPL3')
+depends=('toxcore' 'weechat>=1.0.1')
+makedepends=('git' 'cmake')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+source=("${pkgname}::git+https://github.com/nogaems/tox-weechat"
+        "${_pkgname}-bootstrap.patch")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd "${pkgname}"
+  printf 'r%s.%s' \
+   "$(git rev-list --count HEAD)" \
+   "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${pkgname}"
+  git checkout file_transfer
+
+  patch -p1 -i "${srcdir}/${_pkgname}-bootstrap.patch"
+}
+
+build() {
+  cd "${pkgname}"
+  cmake \
+   -DCMAKE_C_FLAGS="${CFLAGS}" \
+   -DCMAKE_INSTALL_PREFIX="/usr" .
+  make
+}
+
+package() {
+  cd "${pkgname}"
+  make install DESTDIR="${pkgdir}"
+  install -dm755 "${pkgdir}/usr/share/doc/${_pkgname}"
+  install -m644 AUTHORS README.md "${pkgdir}/usr/share/doc/${_pkgname}"
+}