From e926db21580e51653246d9a829243d99e2a4d22c Mon Sep 17 00:00:00 2001
From: Deposite Pirate
Date: Sun, 30 Sep 2018 12:34:37 +0200
Subject: Add the deadbeef filebrowser plugin.

---
 deadbeef-plugin-fb-gtk3-git/.SRCINFO   | 19 +++++++++++++++
 deadbeef-plugin-fb-gtk3-git/.gitignore |  1 +
 deadbeef-plugin-fb-gtk3-git/PKGBUILD   | 42 ++++++++++++++++++++++++++++++++++
 3 files changed, 62 insertions(+)
 create mode 100644 deadbeef-plugin-fb-gtk3-git/.SRCINFO
 create mode 100644 deadbeef-plugin-fb-gtk3-git/.gitignore
 create mode 100644 deadbeef-plugin-fb-gtk3-git/PKGBUILD

(limited to 'deadbeef-plugin-fb-gtk3-git')

diff --git a/deadbeef-plugin-fb-gtk3-git/.SRCINFO b/deadbeef-plugin-fb-gtk3-git/.SRCINFO
new file mode 100644
index 0000000..4f12d08
--- /dev/null
+++ b/deadbeef-plugin-fb-gtk3-git/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = deadbeef-plugin-fb-gtk3-git
+	pkgdesc = A filebrowser plugin for the DeaDBeeF audio player
+	pkgver = r166.g355e614
+	pkgrel = 1
+	url = https://gitlab.com/zykure/deadbeef-fb
+	arch = i686
+	arch = x86_64
+	license = GPL2
+	makedepends = git
+	makedepends = autoconf
+	makedepends = automake
+	makedepends = libtool
+	depends = deadbeef-git
+	depends = gtk3
+	source = deadbeef-fb::git+https://gitlab.com/zykure/deadbeef-fb
+	sha256sums = SKIP
+
+pkgname = deadbeef-plugin-fb-gtk3-git
+
diff --git a/deadbeef-plugin-fb-gtk3-git/.gitignore b/deadbeef-plugin-fb-gtk3-git/.gitignore
new file mode 100644
index 0000000..fcb0988
--- /dev/null
+++ b/deadbeef-plugin-fb-gtk3-git/.gitignore
@@ -0,0 +1 @@
+deadbeef-fb
diff --git a/deadbeef-plugin-fb-gtk3-git/PKGBUILD b/deadbeef-plugin-fb-gtk3-git/PKGBUILD
new file mode 100644
index 0000000..c8ca4a2
--- /dev/null
+++ b/deadbeef-plugin-fb-gtk3-git/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+#
+# Upstream: https://git.metalpunks.info/arch-ports
+
+_pkgname=deadbeef-fb
+pkgname=deadbeef-plugin-fb-gtk3-git
+pkgver=r166.g355e614
+pkgrel=1
+pkgdesc="A filebrowser plugin for the DeaDBeeF audio player"
+arch=('i686' 'x86_64')
+url="https://gitlab.com/zykure/deadbeef-fb"
+license=('GPL2')
+depends=('deadbeef-git' 'gtk3')
+makedepends=('git' 'autoconf' 'automake' 'libtool')
+source=("${_pkgname}::git+https://gitlab.com/zykure/${_pkgname}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+  printf "r%s.g%s" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${_pkgname}"
+  ./autogen.sh
+}
+
+build() {
+  cd "${_pkgname}"
+  CFLAGS="${CFLAGS}" ./configure --prefix=/usr --disable-gtk2
+  make
+}
+
+package() {
+  cd "${_pkgname}"
+  make DESTDIR="${pkgdir}" install
+  rm \
+    "${pkgdir}/usr/share/doc/deadbeef-fb/LICENSE" \
+    "${pkgdir}/usr/share/doc/deadbeef-fb/version"
+}
-- 
cgit v1.2.3-70-g09d2