From 733717d1e623fc9064391e30dcfa0afdbb487641 Mon Sep 17 00:00:00 2001
From: Deposite Pirate
Date: Thu, 28 Mar 2019 21:27:25 +0100
Subject: * New kvirc build without kde and phonon.

	new file:   kvirc-qt-git/.SRCINFO
	new file:   kvirc-qt-git/.gitignore
	new file:   kvirc-qt-git/PKGBUILD
---
 kvirc-qt-git/PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 kvirc-qt-git/PKGBUILD

(limited to 'kvirc-qt-git/PKGBUILD')

diff --git a/kvirc-qt-git/PKGBUILD b/kvirc-qt-git/PKGBUILD
new file mode 100644
index 0000000..ba94a3b
--- /dev/null
+++ b/kvirc-qt-git/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+#
+# Upstream: https://git.metalpunks.info/arch-ports
+
+pkgname=kvirc-qt-git
+pkgver=5.0.0.r7416.9b35d44fd
+_pkgver=5.0.0
+pkgrel=1
+pkgdesc="Qt based IRC-Client"
+arch=('i686' 'x86_64')
+url="http://www.kvirc.net"
+license=('GPL')
+depends=('qt5-base' 'glibc' 'openssl' 'zlib' 'qt5-multimedia' 'qt5-svg' 'qt5-x11extras' 'qt5-webkit' 'enchant')
+makedepends=('python2' 'gettext' 'doxygen' 'extra-cmake-modules' 'zsh' 'cmake' 'git'  'gettext')
+conflicts=('kvirc4' 'kvirc')
+provides=('kvirc' 'kvirc4')
+source=("${pkgname}::git+https://github.com/kvirc/KVIrc.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname}"
+  printf "${_pkgver}.r%s.%s" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+prepare(){
+  cd "${srcdir}/${pkgname}"
+  # Fix overlinking
+  sed -e '/lcrypto/d' -i CMakeLists.txt
+}
+
+build() {
+  cd "${srcdir}"
+  rm -rf build
+  mkdir build
+  cd build
+  cmake ../${pkgname} \
+  -DCMAKE_INSTALL_PREFIX="/usr" \
+  -DCMAKE_BUILD_TYPE:STRING="Release" \
+  -DWANT_PERL="OFF" \
+  -DWANT_GTKSTYLE="ON" \
+  -DWANT_KDE="OFF" \
+  -DWANT_PHONON="OFF" \
+  -DWANT_OSS="OFF" \
+  -DWANT_ESD="ON"
+  make
+}
+
+package() {
+  cd "${srcdir}/build"
+  make DESTDIR="${pkgdir}" install
+}
-- 
cgit v1.2.3-70-g09d2