# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
#
# Upstream: https://git.metalpunks.info/arch-ports

_pkgname=devilutionx
pkgname=devilutionx-git
pkgver=0.5.0.r304.g89dd6a68
pkgrel=1
pkgdesc="Diablo devolved for linux (git version)"
arch=('i686' 'x86_64')
url="https://github.com/diasurgical/devilutionX"
license=('custom:unlicense')
depends=('sdl2_mixer' 'sdl2_ttf' 'libsodium')
makedepends=('git' 'cmake')
provides=("${_pkgname}"="${pkgver}")
install="${_pkgname}".install
source=(
  "${_pkgname}::git+https://github.com/diasurgical/devilutionX.git"
  LICENSE::https://raw.githubusercontent.com/diasurgical/devilutionX/master/LICENSE
  diablo.desktop
  diablo_1_icon_by_mulek169.png
)
sha256sums=('SKIP'
            '88d9b4eb60579c191ec391ca04c16130572d7eedc4a86daa58bf28c6e14c9bcd'
            '1f0b591e2b5d14e69864967c056458a2d845da989b3c4ba251c7a89d49cd9c81'
            'f569210a4217a5e7aa29366376554ffaeae84bdbe278b5335fd3cb37e1d0f82d')

pkgver() {
  cd "${_pkgname}"
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  cd "${_pkgname}"
  rm -rf build64
  mkdir -p build64 && cd build64
  cmake -DBINARY_RELEASE="ON" ..
  make
}

package() {
  cd "${_pkgname}"
  install -vDm755 build64/"${_pkgname}" "${pkgdir}"/usr/bin/"${_pkgname}"
  install -vDm644 LICENSE -t "${pkgdir}"/usr/share/licenses/"${pkgname}"
  install -vDm644 "${srcdir}"/diablo.desktop "${pkgdir}"/usr/share/applications/"${_pkgname}.desktop"
  install -vDm644 "${srcdir}"/diablo_1_icon_by_mulek169.png "${pkgdir}"/usr/share/pixmaps/"${_pkgname}.png"
}