# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
#
# Upstream: https://git.metalpunks.info/arch-ports

_pkgname=lagrange
pkgname=(${_pkgname}-nosse41 ${_pkgname} ${_pkgname}-common clagrange)
pkgver=1.20.5
pkgrel=1
pkgdesc='Beautiful Gemini Client (better packages)'
url='https://git.skyjake.fi/skyjake/lagrange'
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
license=('BSD')
install="$_pkgname.install"
source=("https://github.com/skyjake/$_pkgname/releases/download/v$pkgver/$_pkgname-$pkgver.tar.gz")
makedepends=(
    'cmake'
    'zip'
)
sha256sums=('79f2d451203f534bbd05a8b8f07fe40fa72f4794ffc238f43ad941b7d2450ace')

build() {
    cmake -B build-nosse -S "${_pkgname}-${pkgver}" \
        -DCMAKE_BUILD_TYPE='Release' \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -DENABLE_KERNING=OFF \
        -DENABLE_TUI=ON \
        -DTFDN_ENABLE_WARN_ERROR=OFF \
        -DTFDN_ENABLE_SSE41=OFF \
        -Wno-dev
    make -C build-nosse

    cmake -B build -S "${_pkgname}-${pkgver}" \
        -DCMAKE_BUILD_TYPE='Release' \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -DENABLE_KERNING=OFF \
        -DTFDN_ENABLE_WARN_ERROR=OFF \
        -Wno-dev
    make -C build
}

package_lagrange-common() {
pkgdesc='Common files for Lagrange'
depends=('hicolor-icon-theme')
  install -Dm644 "${_pkgname}-${pkgver}/LICENSE.md" \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"

  cd build
  make DESTDIR="${pkgdir}" install
  rm -rf ${pkgdir}/usr/{bin,share/applications}
}

package_lagrange() {
pkgdesc='Beautiful Gemini Client'
depends=(
    'lagrange-common'
    'fribidi'
    'harfbuzz'
    'libunistring'
    'openssl'
    'pcre2'
    'zlib'
    'sdl2'
    'libwebp'
    'opusfile'
    'mpg123'
    'libjxl'
)
  install -Dm755 build/lagrange \
    "${pkgdir}/usr/bin/lagrange"
  install -Dm644 build-nosse/fi.skyjake.Lagrange.desktop \
    "${pkgdir}/usr/share/applications/fi.skyjake.Lagrange.desktop"
}

package_lagrange-nosse41() {
pkgdesc='Beautiful Gemini Client (for CPUs with no SSE41)'
depends=(
    'lagrange-common'
    'fribidi'
    'harfbuzz'
    'libunistring'
    'openssl'
    'pcre2'
    'zlib'
    'sdl2'
    'libwebp'
    'opusfile'
    'mpg123'
    'libjxl'
)
conflict=('lagrange')
provides=('lagrange')
  install -Dm755 build-nosse/lagrange \
    "${pkgdir}/usr/bin/lagrange"
  install -Dm644 build-nosse/fi.skyjake.Lagrange.desktop \
    "${pkgdir}/usr/share/applications/fi.skyjake.Lagrange.desktop"
}

package_clagrange() {
pkgdesc='Beautiful Gemini Client (text user interface)'
depends=(
    'lagrange-common'
    'libunistring'
    'openssl'
    'pcre2'
    'zlib'
    'ncurses'
)
  install -Dm755 build-nosse/clagrange \
    "${pkgdir}/usr/bin/clagrange"
  install -Dm644 build-nosse/fi.skyjake.clagrange.desktop \
    "${pkgdir}/usr/share/applications/fi.skyjake.clagrange.desktop"
}