# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
#
# Upstream: https://git.metalpunks.info/arch-ports
#
# vim: ts=2 sw=2 noet

pkgname=nginx-mod-fancyindex
_modname="ngx-${pkgname#nginx-mod-}"
pkgver=0.6.0
pkgrel=1
pkgdesc="Fancy indexes module for the Nginx web server"
url="https://github.com/aperezdc/${_modname}"
license=('BSD')
arch=('x86_64' 'i686')
depends=('nginx=1.30.1')
makedepends=('nginx-src')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha256sums=('d212fdc1393261612126def3e091c376adeda5646130b4240093f47b550bc5ef')
# Maxim Dounin <mdounin@mdounin.ru>
validpgpkeys=('B0F4253373F8F6F510D42178520A9993A1C052F8')

prepare() {
  cp -r /usr/src/nginx .
}

build() {
  cd "${srcdir}"/nginx
  CFLAGS="${CFLAGS}" ./configure \
    --add-dynamic-module="../${_modname}-${pkgver}" \
    --with-compat
  make modules
}

package() {
  install -Dvm755 "${srcdir}/nginx/objs/ngx_http_fancyindex_module.so" \
    -t "${pkgdir}/usr/lib/nginx/modules"
  install -Dvm644 "${srcdir}/${_modname}-${pkgver}/LICENSE" \
    -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dvm644 "${srcdir}/${_modname}-${pkgver}/CHANGELOG.md" \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dvm644 "${srcdir}/${_modname}-${pkgver}/README.rst" \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}