# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>

pkgname=xwpe
pkgver=1.5.30a
pkgrel=1
pkgdesc="A Borland IDE-like text editor"
arch=('i686' 'x86_64')
url="http://www.identicalsoftware.com/xwpe"
license=('GPL2')
depends=('ncurses' 'gpm' 'zlib' 'libice' 'libx11')
source=("http://www.identicalsoftware.com/xwpe/$pkgname-$pkgver.tar.gz"
        'xwpe-1.5.30a-makefile.patch')
sha256sums=('fce37a5dd3afd7102a73d187eda8b9d1ab88bf5db649f385b8cd13e72e0c7961'
            'SKIP')

prepare() {
  cd "${pkgname}-${pkgver}"

  # Allow building a version without X
  patch -p1 -i ../xwpe-1.5.30a-makefile.patch
}

build() {
  cd "${pkgname}-${pkgver}"
  CFLAGS="${CFLAGS}" ./configure \
   --prefix=/usr \
   --libdir='${prefix}/share'
  make wpe
  mv wpe wpe.save
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make install \
   prefix="${pkgdir}/usr" \
   MANDIR="${pkgdir}/usr/share/man" \

  (
    cd "${pkgdir}/usr/bin" ; rm -f we wpe
  )

  install -m755 wpe.save "${pkgdir}/usr/bin/wpe"

  (
    cd "${pkgdir}/usr/bin" ; ln -sf wpe we
  )

  install -Dm644 xwpe.desktop \
   "${pkgdir}/usr/share/applications/${pkgname}.desktop"

  install -dm755 "${pkgdir}/usr/share/doc/${pkgname}"

  install -m644 CHANGELOG README \
   "${pkgdir}/usr/share/doc/${pkgname}"
}