if status is-interactive; and not fish_is_root_user

  if test -z "$WEBSEARCH"
    set -x WEBSEARCH 'https://html.duckduckgo.com'
  end

  # Console browsers to look for by order of preference
  set -f browsers 'elinks' 'links' 'lynx' 'w3m'
  set -f found_browser (find_prog $browsers)

  if test -n "$found_browser"

    set -x TUIBROWSER $found_browser

    # If $BROWSER is unset, set it
    if test -z "$BROWSER"
      set -x BROWSER $found_browser
    end

  end

  if test -n "$WAYLAND_DISPLAY"; or test -n "$DISPLAY"; or test (uname) = 'Darwin'

    # Graphical browsers to look for by order of preference
    set -f xbrowsers 'librewolf' 'firefox' 'brave' 'palemoon' 'dillo'
    set -f found_xbrowser (find_prog $xbrowsers)

    if test -n "$found_xbrowser"
      if test -z "$BROWSER"
        set -x BROWSER $found_xbrowser
      end
    end

  end

  # Console gopher browser to look for by order of preference
  set -f gbrowsers 'gopherus' 'ncgopher'
  set -f found_gbrowser (find_prog $gbrowsers)

  if test -n "$found_gbrowser"
    alias gopher "$found_gbrowser"
  end

end