Add hexchat-otr-git.

3 files changed, 54 insertions, 0 deletions

diff --git a/hexchat-otr-git/.SRCINFO b/hexchat-otr-git/.SRCINFO
new file mode 100644
index 0000000..753b8c8
--- /dev/null
+++ b/hexchat-otr-git/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = hexchat-otr-git
+	pkgdesc = OTR support for hexchat
+	pkgver = r50.ga7a6016
+	pkgrel = 2
+	url = https://github.com/TingPing/hexchat-otr
+	arch = i686
+	arch = x86_64
+	license = GPL2
+	makedepends = git
+	makedepends = gnome-common
+	depends = hexchat
+	depends = libotr>=4.1.0
+	provides = hexchat-otr
+	conflicts = hexchat-otr
+	source = hexchat-otr-git::git+https://github.com/TingPing/hexchat-otr
+	md5sums = SKIP
+
+pkgname = hexchat-otr-git
+
diff --git a/hexchat-otr-git/.gitignore b/hexchat-otr-git/.gitignore
new file mode 100644
index 0000000..495fe49
--- /dev/null
+++ b/hexchat-otr-git/.gitignore
@@ -0,0 +1 @@
+hexchat-otr-git
diff --git a/hexchat-otr-git/PKGBUILD b/hexchat-otr-git/PKGBUILD
new file mode 100644
index 0000000..393c3df
--- /dev/null
+++ b/hexchat-otr-git/PKGBUILD
@@ -0,0 +1,34 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+
+pkgname=hexchat-otr-git
+pkgver=r50.ga7a6016
+pkgrel=2
+pkgdesc="OTR support for hexchat"
+url="https://github.com/TingPing/hexchat-otr"
+license=('GPL2')
+arch=('i686' 'x86_64')
+depends=('hexchat' 'libotr>=4.1.0')
+makedepends=('git' 'gnome-common')
+conflicts=('hexchat-otr')
+provides=('hexchat-otr')
+source=("${pkgname}::git+${url}")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname}"
+  printf "r%s.g%s" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${pkgname}"
+  ./autogen.sh
+  CFLAGS="${CFLAGS}" ./configure --prefix="/usr"
+  make
+}
+
+package() {
+  cd "${pkgname}"
+  make DESTDIR="${pkgdir}" install
+}