* Add deadbeef-plugin-lyricbar-git which replaces

  "lyricsbar"

	new file:   deadbeef-plugin-lyricbar-git/.SRCINFO
	new file:   deadbeef-plugin-lyricbar-git/.gitignore
	new file:   deadbeef-plugin-lyricbar-git/PKGBUILD
	new file:   deadbeef-plugin-lyricbar-git/deadbeef-lyricbar-makefile.patch

1 files changed, 44 insertions, 0 deletions

diff --git a/deadbeef-plugin-lyricbar-git/PKGBUILD b/deadbeef-plugin-lyricbar-git/PKGBUILD
new file mode 100644
index 0000000..93c509b
--- /dev/null
+++ b/deadbeef-plugin-lyricbar-git/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+#
+# Upstream: https://git.metalpunks.info/arch-ports
+
+_pkgname=deadbeef-lyricbar
+pkgname=deadbeef-plugin-lyricbar-git
+pkgver=r60.ga08374c
+pkgrel=1
+pkgdesc="DeaDBeeF lyric bar plugin"
+arch=('i686' 'x86_64')
+url="https://github.com/C0rn3j/deadbeef-lyricbar"
+license=('MIT')
+depends=('deadbeef-git' 'libxml++')
+optdepends=('gtkmm3' 'gtkmm')
+makedepends=('git')
+source=("${_pkgname}::git+${url}"
+        "${_pkgname}-makefile.patch")
+sha256sums=('SKIP'
+            '7c3088f5e4f703aca04011158e27087643410a189c2dcbb1fbd65fdbca8b216f')
+
+pkgver() {
+  cd "${_pkgname}"
+  printf "r%s.g%s" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${_pkgname}"
+
+  # Arch compile FLAGS
+  patch -p1 -i ../${_pkgname}-makefile.patch
+}
+
+build() {
+  cd "${_pkgname}"
+  make COPTS="${CFLAGS}" CXXOPTS="${CXXFLAGS}"
+  make COPTS="${CFLAGS}" CXXOPTS="${CXXFLAGS}" gtk2
+}
+
+package() {
+  cd "${_pkgname}"
+  make prefix="${pkgdir}/usr" install
+}