* Wanted to test this as I couldn't find any screenshots. It turns out

  rolo is a joke of an address book in which you must edit vCards with a
  text editor. Nevertheless, since these PKGBUILDs I made are much better
  than those found on the AUR they might be useful to someone.

	new file:   libvc-git/.SRCINFO
	new file:   libvc-git/PKGBUILD
	new file:   rolo-git/.SRCINFO
	new file:   rolo-git/PKGBUILD

1 files changed, 38 insertions, 0 deletions

diff --git a/rolo-git/PKGBUILD b/rolo-git/PKGBUILD
new file mode 100644
index 0000000..db7ef59
--- /dev/null
+++ b/rolo-git/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+#
+# Upstream: https://git.metalpunks.info/arch-ports
+
+_pkgname=rolo
+pkgname=${_pkgname}-git
+pkgver=0.392.8446eb7
+pkgrel=1
+pkgdesc="Ncurses vCard viewer and editor"
+arch=('i686' 'x86_64')
+url="https://github.com/libvc/rolo"
+license=('GPL')
+depends=('ncurses' 'libunac' 'libvc-git')
+makedepends=('autoconf')
+conflicts=(rolo)
+provides=(rolo)
+source=("${_pkgname}::git+${url}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+  echo "0.$(git rev-list --count HEAD).$(git describe --always)"
+}
+
+build() {
+  cd "${_pkgname}"
+  autoreconf -f -i
+  CFLAGS="${CFLAGS}" ./configure --prefix=/usr --mandir=/usr/share/man
+  make
+}
+
+package() {
+  cd "${_pkgname}"
+  make DESTDIR="$pkgdir" install
+  install -dm755 "${pkgdir}/usr/share/doc/${_pkgname}"
+  install -m644 AUTHORS NEWS README THANKS TODO \
+    "${pkgdir}/usr/share/doc/${_pkgname}"
+}