* Add youtubedr.

	new file:   youtubedr/.SRCINFO
	new file:   youtubedr/PKGBUILD

1 files changed, 41 insertions, 0 deletions

diff --git a/youtubedr/PKGBUILD b/youtubedr/PKGBUILD
new file mode 100644
index 0000000..b887205
--- /dev/null
+++ b/youtubedr/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Deposite Pirate <dpirate@metalpunks.info>
+#
+# Upstream: https://git.metalpunks.info/arch-ports
+
+_pkgname=youtube
+pkgname=youtubedr
+pkgver=2.1.1
+pkgrel=1
+pkgdesc="Download YouTube videos"
+arch=('x86_64')
+url="https://github.com/kkdai/youtube"
+license=('MIT')
+depends=('glibc')
+makedepends=('go' 'git')
+source=("git+$url#tag=v$pkgver")
+sha256sums=('SKIP')
+
+build() {
+    cd "${srcdir}/${_pkgname}"
+    GOOS=linux GOARCH=amd64 \
+    CGO_CPPFLAGS="${CPPFLAGS}" \
+    CGO_CFLAGS="${CFLAGS}" \
+    CGO_CXXFLAGS="${CXXFLAGS}" \
+        go build -v \
+            -trimpath \
+            -buildmode=pie \
+            -mod=readonly \
+            -modcacherw \
+            -ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
+            -o build ./cmd/...
+}
+
+check() {
+    cd "${srcdir}/${_pkgname}"
+    go test
+}
+
+package() {
+    cd "${srcdir}/${_pkgname}"
+    install -Dm755 build "$pkgdir/usr/bin/${pkgname}"
+}