1 files changed, 47 insertions, 0 deletions
diff --git a/libvc-git/PKGBUILD b/libvc-git/PKGBUILD
new file mode 100644
index 0000000..3e2a038
--- /dev/null
+++ b/libvc-git/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
+#
+# Upstream: https://git.metalpunks.info/arch-ports
+
+_pkgname=libvc
+pkgname=${_pkgname}-git
+pkgver=0.91.3834e2f
+pkgrel=1
+pkgdesc="vCard library, part of rolo project."
+arch=('i686' 'x86_64')
+url="https://github.com/libvc/libvc"
+license=("LGPL")
+depends=('glibc')
+makedepends=('flex' 'git' 'autoconf')
+conflicts=(libvc)
+provides=(libvc)
+source=("${_pkgname}::git+${url}")
+sha256sums=('SKIP')
+options=(!libtool)
+
+pkgver() {
+  cd "${_pkgname}"
+  echo "0.$(git rev-list --count HEAD).$(git describe --always)"
+}
+
+#prepare() {
+#  cd "${_pkgname}"
+#
+#  # Improve vCard parsing times (doesn't apply cleanly)
+#  patch -p1 -i patches/improve-parsing-time-large-vcards.patch
+#  patch -p1 -i patches/fix-segfault.patch
+#}
+
+build() {
+  cd "${_pkgname}"
+  autoreconf -f -i
+  CFLAGS="${CFLAGS}" ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd "${_pkgname}"
+  make DESTDIR="${pkgdir}" install
+  install -dm755 "${pkgdir}/usr/share/doc/${_pkgname}"
+  install -m644 AUTHORS NEWS README THANKS TODO \
+    "${pkgdir}/usr/share/doc/${_pkgname}"
+}